Awesome-o Project

Dit is het verslag van mijn Awesom-o project.
Awesom-o is een karakter uit de gelijknamige aflevering van Southpark.
De naam van de robot AWESOM-O verwijst naar de robot ASIMO. uit Japan

Ik wilde graag een Obstacle Avoidance robotje bouwen en het leek me leuk om hem het uiterlijk van Awesom-o te geven.
Dit is mijn robot:

Dit is nog een prototype, gemaakt van restjes hout en karton. De hardware en software ontwikkel ik terwijl ik verschillende dingen uitprobeer.

Arduino Nano

De heeft een Arduino nano om de wielen en sensoren te bedienen. De arduino nano is tegenwoordig zo goedkoop dat een losse microcontroller niet eens meer de moeite waard is. Ik kocht 5 nano's voor €13,55 bij Banggood.com

Video 1, intro van dit project

Aandrijving

update Maart 2015:

Iets over de aandrijving. Awesom-o heeft 2 aangedreven wielen.
Deze wielen, plus motor zijn te koop op ebay of in de bekende chinese webwinkels. Per stuk kosten ze ongeveer €3,50
robot wheel

Om deze motors aan te sturen met Arduino, en de draairichting te regelen maak ik gebruik van een H-Brug. Elke motor heeft zijn eigen H-Brug nodig.

Werking van de H-brug:
Het schema hierboven geeft de H-Brug weer. Helemaal links en rechts zie je de stuursignalen, de motor draait nu rechtsom (met de klok mee). Als de 5 volt en nul volt signalen worden omgedraaid zal ook de draairichting van de motor omdraaien.
De onderste transistor wordt aangesloten om een pwm pin van de Arduino (bijvoorbeeld pin 5). Deze geeft ons snelheidsregeling.

In deze video leg ik het uitgebreid uit.

Opmerking over de snelheidsregeling: Pas op, de snelheidsregeling zorgt ervoor dat de motortjes erg veel storing geven op de voeding van de robot. De Arduino kan hier last van hebben en spontaan resetten. Op dit moment gebruik ik de snelheidsregeling zelf niet.

Afstandsensor

update 2 April 2015:

De Robot maakt gebruik van een ultrasone afstandssensor om zijn omgeving af te speuren.
sensor

Deze sensor is te koop op ebay en alle bekende (en onbekende) Chinese webwinkels

Het aansluiten van deze sensor is eenvoudig, er zijn 4 pootjes, Voeding, Ground, Trigger en Echo.

sensor

Hier is de Arduino (voor Uno of Nano) code om deze sensor te testen:

#define trigPin 12
#define echoPin 11
#define led 13

void setup(){
 Serial.begin(9600);
 pinMode(trigPin, OUTPUT);
 pinMode(echoPin, INPUT);
 pinMode(led, OUTPUT);
}

void loop(){
  int distance;
  distance = getDistance();
  if (distance < 4) {
    digitalWrite(led,HIGH);
  } else {
    digitalWrite(led,LOW);
  }
   
  if (distance >= 200 || distance <= 0) {
    Serial.prinln("Out of range");
  } else {
    Serial.print(distance);
	Serial.prinln(" cm");
  }  
  delay(500);
}

int getDistance(){
  long duration, distance;
  digitalWrite(trigPin,LOW);
  delayMicroseconds(5);
  digitalWrite(trigPin,HIGH);
  delayMicroseconds(10);
  digitalWrite(trigPin,LOW);
  duration = pulseIn(echoPin, HIGH);
  distance = (duration/2) / 29.1;
  return distance;
}

In deze video leg ik het uitgebreid uit.

Servos op Arduino

update 9 April 2015:

Het hoofd van awesome-o wordt door een servo bestuurd. Sero's kun je op nog veel meer dingen toepassen en daarom is het leuk om daar eens mee te expirimenteren.

Dit zijn de 3 servo's die ik gebruik. Ik heb deze puur op prijs geselecteerd

	De mini servo SG90 van towerpro. Dit is een erg kleine servo, en spotgoedkoop. Het is natuurlijk niet de meest krachtige servo maar als een klein formaat belangrijk is, is dit een optie. Prijs op ebay (prijs is van augustus 2015): minder dan €2
	De SG5010 van towerpro. Met de SG5110 krijg je veel servo voor je geld. Hij is niet duur en erg sterk. Deze servo heb ik gebruikt in mijn Useless Machine (zie youtube Link) Prijs op ebay (prijs is van augustus 2015): minder dan €5
	De S3003 van Futuba. Dit is een alternatief voor de SG5110, iets goedkoper nog. Zelfde formaat en net zo sterk. Prijs op ebay (prijs is van augustus 2015): minder dan €3.50

Servo's aansluiten op Arduino

Elke servo heeft dezelfde 3 polige aansluiting, soms verschillen de kleuren een beetje maar altijd hebben ze: Ground, Power en Signal.
De ground en power sluit je aan op de GND en 5V pinnen van Arduino.
De signaaldraad gaat in mijn voorbeeld naar pin 6. Je mag ook een andere pin kiezen als dat beter uit komt.
servo to arduino

Als jet het volgens het plaatje hierboven aansluit kun je met de volgende sketch testen of de servo goed werkt met de standaard functies van Arduino:

#include <Servo.h>
 
Servo myservo;          
 
void setup()
{
  myservo.attach(6,600,2400);  // servo on pin 6. 
                               // Signal goes from 600 microseconds (for 0 degrees)
                               // to 2400 microseconds (for 180 degrees)
}
 
 
void loop()
{
  // go to position 0
  myservo.write(0);
  // delay 3 seconds
  delay(3000);
  
  // go to position 180
  myservo.write(180);
  // delay 3 seconds
  delay(3000);
 
}

Met wat geluk zie je met deze sketch de servo van 0 naar 180 graden gaan (en weer terug).

Maar in de praktijk blijkt dat niet alle servos hetzelfde zijn, de aansturing verschilt per merk en type. Hoe je dat oplost laat ik zien in mijn video over servo's op Arduino.
In de video gebruik ik deze sketch om de signaallengte van de servo te vinden

// servo op pin 6
#define servo 6

void setup() {
  pinMode(servo,OUTPUT);
  digitalWrite(servo,LOW);

}

void loop() {
  digitalWrite(servo,HIGH);
  delayMicroseconds(700);  // varieer deze tussen 500 en 4000
                           // om de minimale en maximale uitslag
                           // van de servo te vinden
  digitalWrite(servo,HIGH);
  delay(18);
}

Bekijk de video!

Geluid afspelen met Arduino

update 23 April 2015:

Met behulp van een micro SD Card reader is het mogelijk om verschillende geluiden of muziekfragmenten af te spelen vanaf je Arduino project.
Ik gebruik de volgende Card Reader: Sound with Arduino

Ik kocht de reader bij BangGood.com, prijs: 5 stuks voor €6,96 (prijs is van augustus 2015)

SD Card Reader aansluiten op arduino

De card reader heeft een S.P.I. interface, we maken gebruik van de standaard clock en datalijnen (CLK, MOSI en MISO)
De CS (Slave select) pin mag je zelf kiezen, ik neem pin 4.
Sound with Arduino

Software

Voor de software ga je naar GitHub.com en je gebruikt de zoekterm TRMPCM om de juiste library te vinden
Ik raad aan om de versie van GitHub.com te nemen maar hier is een lokale link: Link

Bij deze library zit een standaard voorbeeld met de naam basic. Dat kun je gebruiken om de setup te testen

WAV Files voorbereiden

Je kunt niet zomaar elk formaat afspelen met de TRMPCM library, de files moeten een specifiek formaat hebben. Ik gebruik Audacity om de files om te zetten in het juiste formaat. Audacity is gratis en beschikbaar voor windows, Linux en Mac.

Stap 1:

Open het geluidsfragment (begin met iets kleins!) en maximaliseer het volume.

Stap 2:

Stel Audacity in op een sample frequency van 16k
Sound with Arduino

Stap 3:

Bewaar of exporteer de file als other uncompressed, unsigned 8 bit, Microsoft Wav (zie afbeelding)

Daarna is het slechts een kwestie van het wav bestand op de SD Card zetten de voorbeeld sketch een beetje aanpassen zodat de bestandsnaam op de SD Card overeen komt met de bestandsnaam in de sketch.

In de video hieronder leg ik het allemaal uit.

Tilt Sensor en Low Battery detection

Ik heb nog twee nieuwe functies voor de robot bedacht:
- Een tilt sensor, zodat hij weet wanneer hij omvalt of opgepakt wordt.
- Een Batterij monitor, zodat de robot zelf in de gaten houdt of de batterij nog genoeg kracht heeft.

Het Schema

Hier is het complete schema (Klik om het hele schema te zien en te downloaden)

CAD tekeningen voor het lichaam

Het lichaam van deze robot is een triplex frame met een skin van karton.
De invulling kartonnen buitenkant laat ik geheel aan jou over, maar het houten frame kun je hier downloaden: het hoofd
zijkanten van het lijf
voor en achterkant van het lijf
bovenkant van het lijf
onderkant van het lijf
subframe aan de onderkant (voor de motors en de wielen)
de wielen

Hier zijn wat fotos die helpen om de puzzle in elkaar te zetten :-).. Succes!

Final Sketch

Dit is de uiteindelijke sketch.

// Sound index:
// 1.wav = I am the awesom-o 4000
// 2.wav = Must dispense oil waste
// 3.wav = Scanning
// 4.wav = Battery LOW
// 5.wav = Unknown Function
// 6.wav = Ah!
// 7.wav = I am Awesom-o (short version)
// 8.wav = awesom-o does not understand
// 9.wav = Lame!
// 10.wav = Weak!
// 11.wav = Not Cool!
// 12.wav = screw you guys, I going home
// 13.wav = ti ti ti tu tu tu
// 14.wav = no way
// 15.wav = awesom-o is reorganising your stuff
// 16.wav = awesom-o wil answer the door


#include <EEPROM.h>
#include <SD.h>  
#include <TMRpcm.h>  
#include <SPI.h>



float voltage = 0.0;
int SD_reader   = 10; // chip select van sd card reader
int audio_out   = 9;
int trigPin     = 8;
int echoPin     = 7;
int servo1      = 6;
int speedcontrl = 5;
int RCSensor    = 2;
int irSensor    = 3;

int servoEnable = A0;  // hier op zit een extra transistor om de servo stroomloos te maken als hij niet gebruikt wordt.
int redled      = A1;
int wheel1A     = A2;   
int wheel1B     = A3; 
int wheel2A     = A4; 
int wheel2B     = A5;

int midPos;
int kopPos;

int motorSpeed;
int maxMotorSpeed;
int minMotorSpeed;
int turningSpeed;

int commando=0;
int soundcommando=0;
int soundEnable = 4;

boolean speedcontrol=true;

TMRpcm tmrpcm; 


void setup() {    

  pinMode(speedcontrl, OUTPUT);
  if (speedcontrol) {analogWrite(speedcontrl,0);} else { digitalWrite(speedcontrl,LOW); }  // set the motor speed to minimal (slow start)
 
 
  
  pinMode(trigPin, OUTPUT);
  pinMode(echoPin, INPUT);
//  pinMode(irSensor, INPUT);
  if (EEPROM.read(10) != 10) {
    midPos=90;
  }
  else {
    midPos = EEPROM.read(0);
  }

  
  pinMode(redled, OUTPUT);  digitalWrite(redled,LOW); 
  pinMode(servoEnable, OUTPUT); digitalWrite(servoEnable,LOW); 
  
  pinMode(wheel1A, OUTPUT);    digitalWrite(wheel1A, LOW);
  pinMode(wheel1B, OUTPUT);    digitalWrite(wheel1B, LOW); 
  pinMode(wheel2A, OUTPUT);    digitalWrite(wheel2A, LOW);
  pinMode(wheel2B, OUTPUT);    digitalWrite(wheel2B, LOW);
  pinMode(soundEnable, OUTPUT);digitalWrite(soundEnable,HIGH); 
  pinMode(RCSensor, INPUT);  // Remote controll Sensor
  digitalWrite(RCSensor,HIGH); 
  Serial.begin(9600);
  Serial.println("versie 0");
  
  
  // Move the head to the mid position
  pinMode(servo1, OUTPUT);  
  lookAhead();
  delay(100);

  if (!SD.begin(SD_reader)){
    digitalWrite(redled,HIGH);
    delay(1000);
  };
  tmrpcm.speakerPin = audio_out;
  tmrpcm.volume(1);
  digitalWrite(audio_out,HIGH);
  digitalWrite(soundEnable,LOW);
  tmrpcm.play("1.wav");
  delay(2500);
  digitalWrite(soundEnable,HIGH);
 
 
 
  // blink the red led 5 times
  for (int x=0; x<5; x++){
    digitalWrite(redled,HIGH);
    delay(60);
    digitalWrite(redled,LOW);
    delay(60);
  }
 
  
  
  attachInterrupt(0, getSignal, FALLING); // Remote controll Sensor on pin 2

  minMotorSpeed = 180;
  maxMotorSpeed = 255;
  turningSpeed = 200;
  motorSpeed = minMotorSpeed; 
  if (speedcontrol) {analogWrite(speedcontrl,minMotorSpeed);} else { digitalWrite(speedcontrl,LOW); }  // set the motor speed to minimal (slow start)
 

}

void loop() {   
  if (commando==999) {
    tmrpcm.play("4.wav"); 
    delay(20000);    
  }
  // read the battery voltage
  voltage = (analogRead(A6) * 8.5) / 1024;
  if(voltage < 7) {
    commando=999;
    }
    
  if (soundcommando==245) {
    playShortClip();
    delay(250);
    soundcommando=0;
  }
   
  if (commando==10) {
    if (speedcontrol) {
      motorSpeed = motorSpeed + 10; // increase the motor speed to max
      if (motorSpeed >= maxMotorSpeed) {
          motorSpeed = maxMotorSpeed;
          digitalWrite(speedcontrl,LOW);
         }
      analogWrite(speedcontrl, motorSpeed); // set the motor speed (pwm controlled)
      } else {
        digitalWrite(speedcontrl,HIGH);
        }
    forward();
    delay(100);          
    avoidObstacles();
  } else park();

  if (commando==1) {
  lookRound();
  commando=0;
  }
 
  if (commando==2) {
  // hiermee stel ik de middenpositie van het hoofd bij
  // commando 2 is verbonden aan een knop op de afstandsbediening
  midPos = midPos + 2;
  commando=0;
  EEPROM.write(0, midPos); // bewaar de nieuwe positie in de eeprom
  EEPROM.write(10, 10); // en deze is zodat hij weet dat de infomatie op adres 0 geschreven is
  delay(100);
  lookAhead(); 
 
  }
  if (commando==3) {
  // hiermee stel ik de middenpositie van het hoofd bij
  // commando 3 is verbonden aan een knop op de afstandsbediening
  midPos=midPos-2;
  commando=0;
  EEPROM.write(0, midPos);  // bewaar de nieuwe positie in de eeprom
  EEPROM.write(10, 10); // en deze is zodat hij weet dat de infomatie op adres 0 geschreven is
  delay(100);
  lookAhead(); 
  }  
 
  if (commando==242) {BackupLeftTurn(); commando=0;} // om de bochtjes te testen
  if (commando==238) {BackupRightTurn(); commando=0;} // om de bochtjes te testen
  if (commando==234) {BackupTurnAround(); commando=0;} // om de bochtjes te testen
}

void forward(){  wheel_L(2);   wheel_R(2); }

void reverse(){  
  if (speedcontrol) { analogWrite(speedcontrl, turningSpeed); }
  wheel_L(1);  wheel_R(1); 
  }

void park(){
  wheel_L(0);  wheel_R(0);
  
  motorSpeed=minMotorSpeed;
}

void powerbreak(){
  // Remmen door de wielen achteruit te laten draaien.
  reverse();
  delay(20);
  park();
}

  
void wheel_L (int d) {
  // d = 0  Stop
  // d = 1  Forward
  // d = 2  Reverse
  if (commando==0) {d=0;}
  if (d==0) {
    digitalWrite(wheel1A, LOW);
    digitalWrite(wheel1B, LOW);
  }
 
  if (d==0){return;}
  
  if (d==1) {
    digitalWrite(wheel1A, LOW);
    digitalWrite(wheel1B, HIGH);
  }
  if (d==2) {
    digitalWrite(wheel1A, HIGH);
    digitalWrite(wheel1B, LOW);
  }

}

void wheel_R (int d) {
 
 // d = 0  Stop
 // d = 1  Forward
 // d = 2  Reverse
 
 // commando = 0 betekend Stoppen
  if (commando==0){d=0;}
  if (d==0) {
    digitalWrite(wheel2A, LOW);
    digitalWrite(wheel2B, LOW);
  }
 
  if (d==0){return;}
 
  if (d==1) {
    digitalWrite(wheel2A, LOW);
    digitalWrite(wheel2B, HIGH);
  }
  if (d==2) {
    digitalWrite(wheel2A, HIGH);
    digitalWrite(wheel2B, LOW);
  }

}

void turn(int d, int t) {
  // d = 1 Turn Left
  // d = 2 Turn Right
  // d = 10 Turn Left sharp
  // d = 20 Turn Right sharp
  // t = duration in ms
  
  if (speedcontrol) { analogWrite(speedcontrl, turningSpeed); }
  
  if (d==1) {
    wheel_L(0);
    wheel_R (1);
    delay(t);
    wheel_R (0) ;  
  }
 
  if (d==2) {
    wheel_R(0);
    wheel_L (1);
    delay(t);
    wheel_L (0)    ;
  }
  if (d==10) {
    wheel_L(2);
    wheel_R (1);
    delay(t);
    wheel_R (0) ;  
    wheel_L (0) ;  
  }
 
  if (d==20) {
    wheel_R(2);
    wheel_L (1);
    delay(t);
    wheel_L (0)    ;
    wheel_R (0)    ;
  }
}


void getSignal() {
  // dit is voor de afstandsbediening
  noInterrupts();
  int  countLow=0;
  int  countHigh=0;
  bool pinstatus = 0;
  int lenghts[32];
  String hstr;
  int result =0;
  pinstatus = (PIND & (1<<PD2));
  countLow=0;
  while (pinstatus==0) {                                     
    countLow++;
    delayMicroseconds(1);   
    pinstatus = (PIND & (1<<PD2));
  }
  if (countLow < 5000) { interrupts(); return;}
 
  while (pinstatus==1) {                                     
    countHigh++;
    delayMicroseconds(1);   
    pinstatus = (PIND & (1<<PD2));
  }
  if (countHigh < 2000) { interrupts(); return;}
 
  for (int x=0; x<32; x++){
    countHigh=0;
    while (pinstatus==0) { pinstatus = (PIND & (1<<PD2)); }
    while (pinstatus==1) {                                     
      countHigh++;
      delayMicroseconds(1);   
      pinstatus = (PIND & (1<<PD2));
    }
    lenghts[x]=countHigh;
  }
int pc=0;
  for (int i=24; i<32; i++) {
   
     if (lenghts[i] > 500) {
       result = result | (1 << pc++);
       hstr = hstr + "1";
     }
     else{
       //result = result | (0 << pc++);
       pc++;
       hstr = hstr + "0";
     }
    }

    if (result==255 && commando!=10) {
      commando=10;
    } else {
      commando=0;     
    }
    
    if (result==250){
     // enter button
     commando=1;
    }
    
    if (result==245){
     // enter button
     soundcommando=245;
    }
    if (result==251){
     // enter button
     commando=2;
    }
    if (result==249){
     // enter button
     commando=3;
    }
   
    if (result==242){
     // vol up
     commando=242;
    }
   
    if (result==238){
     // vol down
     commando=238;
    }
   
    if (result==234){
     // play pause
     commando=234;
    }
   
  interrupts();
}


void lookRound(){
  lookRight();
  delay(550);
  lookLeft();
  delay(550);
  lookAhead();
  }

void lookRight(){
  kopPos = 5;
  setServo(servo1,kopPos);
  delay(50);
}

void lookLeft(){
  kopPos = 150;
    setServo(servo1,kopPos);
  delay(50);
   
}

void lookAhead(){
  kopPos = midPos;
  setServo(servo1,kopPos);
  delay(50);
}

int getDistance(){
  // dit is voor de afstandsmeter
  noInterrupts();
  long duration, distance;
  digitalWrite(trigPin, LOW);  
  delayMicroseconds(2); 
  digitalWrite(trigPin, HIGH);
  delayMicroseconds(10); 
  digitalWrite(trigPin, LOW);
  duration = pulseIn(echoPin, HIGH);
  distance = (duration/2) / 29.1;
  interrupts();
  return distance;
}

void avoidObstacles(){
 
  int dl=0;
  int dr=0;
 
  int d = getDistance();
 // Serial.print(d);
 // Serial.println(" cm");
  if (d<25) {
     digitalWrite(redled,HIGH);
     powerbreak();
     playShortClip();
     park();
     lookLeft();
     delay (300);
     dl=getDistance();
     lookRight();
     delay (300);
     dr=getDistance();
     lookAhead();
     delay(200);
     d=getDistance();
     if (d<25) {
       if ((dl<30) & (dr<30)) {
         // turn around
         BackupTurnAround();
       digitalWrite(redled,LOW);
   
       return;
       }
      
       if (dl > dr) {
        // Go Left
           BackupRightTurn();  
           playShortClip();
   
           }
        else {
         // Go right
           BackupLeftTurn(); 
           playShortClip();
   
        }
     } else {
       // the obstacle seems to be gone, carry on straight
       playShortClip();
 
     }

  }
  digitalWrite(redled,LOW);
  
}
void setServo(int pin, int degr) {
 
//  Towerpro 5010 
  int maxValue=3300;
  int minValue=640;

// Towerpro 9g microservo
//  int maxValue=2700;
//  int minValue=700;
  static int lastpos;
digitalWrite(servoEnable,HIGH);   
  for (int x=0; x< 5 + ceil(abs(lastpos-degr) * 0.3) ; x++){
    digitalWrite(pin,HIGH);
    delayMicroseconds(minValue + ((maxValue-minValue)/180) * degr) ; 
    digitalWrite(pin,LOW);
    delay(18);
  }
  lastpos = degr;
  digitalWrite(servoEnable,LOW); 

}



void BackupLeftTurn(){
 // analogWrite(speedcontrl, maxMotorSpeed);
  reverse() ;
  delay(300);
 // analogWrite(speedcontrl, turningSpeed);
  turn(1, 400);
  motorSpeed =minMotorSpeed;
}

void BackupRightTurn(){
 // analogWrite(speedcontrl, maxMotorSpeed);
  reverse() ;
  delay(300);
 // analogWrite(speedcontrl, turningSpeed);
  turn(2, 400);
  motorSpeed =minMotorSpeed;
}

void BackupTurnAround(){
 // analogWrite(speedcontrl, maxMotorSpeed);
  reverse() ;
  delay(300);
  park();
  delay(200);
//  analogWrite(speedcontrl, turningSpeed);
  turn(10, 500);
  motorSpeed =minMotorSpeed;
 
}

void playShortClip() {
  noInterrupts();
  // play a (short) clip
  // the short ones are: 17, 9, 10, 13, 14, 16, 11, 15, 7
  int randNumber = random(7);
  
  static int lastnumber;

  while (randNumber == lastnumber) {randNumber = random(10);} 
  
  switch (randNumber) {
  case 0:
    tmrpcm.play("17.wav"); delay(750); break;
  case 1:
    tmrpcm.play("9.wav");delay(600); break;
  case 2:
    tmrpcm.play("10.wav"); delay(600); break;
  case 3:
    tmrpcm.play("13.wav"); delay(1600); break;
  case 4:
    tmrpcm.play("14.wav"); delay(650); break;
  case 5:
    tmrpcm.play("16.wav");delay(1600); break;
  case 6:
    tmrpcm.play("11.wav"); delay(2300);break;  
  case 7:
    tmrpcm.play("15.wav"); delay(2700);break;
  case 8:
    tmrpcm.play("7.wav");delay(1100); break;
  case 9:
    tmrpcm.play("13.wav"); delay(1600); break;
    
  }
  lastnumber = randNumber;
  interrupts();
}