Dark Awesom-o

Oktober 2023:
Awesom-o is een personage van de Comedy Central-reeks South Park. De aflevering AWESOM-O is aflevering 116 (#805) en is voor het eerst uitgezonden op 14 april 2004.
In deze aflevering verkleed Eric zich als robot om Butters voor de gek te houden. De grap loopt natuurlijk uit de hand.
De Robot Awesom-o is een verwijzing naar de Japanse Robot van Honda 'ASIMO'

Mijn versie van Awesom-o wijkt nogal af van het orgineel.. kijk de video!.

Tinkercad Ontwerp.

Bijna de hele robot is geprint met de 3d printer. Je kunt het ontwerp hier vinden: Link

Onderdelen

Dit zijn de onderdelen..

ESP32 D1 Mini

Ik gebruikte een ESP32.
Klik op het plaatje voor een link

Neopixels

Ik gebruikte 3 van deze strips.

En ook twee van deze cirkels:

En twee losse Neopixels (achter de mond)

H-Brug Module

Dit is een H-Brug module om twee gelijkstroom motoren aan te sturen.

Motors

De motortjes komen van ebay. Ze bestaan in verschillende snelheden, ik gebruik de 200rpm variant.
Deze had ik al heel lang liggen, ze zijn niet makkelijk te vinden. Op Aliexpress kun je het ook proberen.

Rupsbanden

De rupsbanden kocht ik op ebay, ze zijn niet altijd goed te vinden dus ik hoop dat deze link werkt

Accu

ik bestelde deze accu bij Conrad. Het is een 11.1Volt LiPo accu met 3 cellen.

Voor deze accu heb je een oplader nodig, ik gebruik deze:

Spanningsregelaar

Dit is de LM2596 instelbare spanningsregelaar.
Je moet deze afregelen een uitgangsspanning van 5 volt

Luidsprekers

Deze kleine luidsprekertjes komen uit een Samsun telefoon. Je kunt ze vinden op AliExpress. Als de link niet werkt kun je zoeken op "Samsung phone speaker".

Mini MP3 Speler

Voor de geluiseffecten gebruikte ik deze kleine mp3 speler. Het micro sd kaartje is niet inbegrepen.
Deze module heeft een ingebouwde versterker dus je kunt er rechtstreeks een luidspreker op aansluiten.

Kleine Stappenmotor

Om het hoofd te laten bewegen gebruik ik de volgende stappenmotor.
Deze bestaat in 12volt en 5 volt variant. Ik gebruikte de 12volt variant

Stappenmotordriver

Om de stappenmotor voor het hoofd aan te sturen gebruik ik deze driver:
Deze driver maakt het aansturen erg eenvoudig.

Sonar Sensor

In het hoofd (in de ogen) zit een sonar sensor om de afstand tot objecten te meten
Het is de HC-SR04 sensor.

Micro switches

De robot heeft 4 bumpers om lage objecten te detecteren. Deze bumpers maken gebruik van schakelaartjes

Naast bovenstaande onderdelen heb je natuurlijk nog meer nodig, de standaard dingen:
- draad
- weerstandjes
- 2 rode leds
- krimpkous
- soldeerbout en tin
- multimeter

Het Schema

Dit is het schema, deel 1:

Klik om te vergroten!

Deel 2:

Klik om te vergroten!

Arduino Sketches

Sketch uit video 1

In de eerste video laat ik het onderstel rijden met behulp van een bluetooth app.

#include "BluetoothSerial.h"

BluetoothSerial SerialBT;

// #define output_x1  0 // as input it is always pulled up. As output it outputs PWM signal at boot
// #define gpoi    1    // TX pin, better not use
// #define output_x2  2 // connected to on-board LED, must be left floating or LOW to enter flashing mode
// #define gpoi    3 // RX pin, better not use
#define LED1       4 
#define neopxls    5 // also SS (slave select) for SPI bus, outputs PWM signal at boot
// #define gpoi    6 // Cannot use, connected to the integrated SPI flash
// #define gpoi    7 // Cannot use, connected to the integrated SPI flash
// #define gpoi    8 // Cannot use, connected to the integrated SPI flash
// #define gpoi    9 // Cannot use, connected to the integrated SPI flash
// #define gpoi   10 // Cannot use, connected to the integrated SPI flash
// #define gpoi   11 // Cannot use, connected to the integrated SPI flash
#define echo      12 // oke to use but boot fails if pulled high
#define LED2      13
#define bumper1   14 // outputs PWM signal at boot  // rear right bumper
// #define gpoi   15 // outputs PWM signal at boot
#define RXD2      16 // RX for serial2
#define TXD2      17 // TX for serial2
#define h3        18 // also CLOCK for SPI bus
#define h2        19 // also MISO for SPI bus
#define step      21 // also i2c DATA pin
#define dir       22 // also i2c CLOCK pin
#define h1        23 // also MOSI for SPI bus
#define servoPin2 25 // 
#define h4        26
#define servoPin1 27
#define trigger   32
#define bumper3   33                          // front right bumper
#define bumper2   34 // input only            // rear left bumper
#define bumper4   35 // input only            // front left bumper
//#define input_x1  36 // input only
#define dfNotBusy 39 // input only // DF Player Busy signal (active low).

void setup() {
  // start the bluetooth serial connection
  SerialBT.begin("Awesomo32"); //Bluetooth device name 
  Serial.begin(115200);

  // H-Bridge
  pinMode(h1, OUTPUT);
  pinMode(h2, OUTPUT);
  pinMode(h3, OUTPUT);
  pinMode(h4, OUTPUT);

  digitalWrite(h1,0);
  digitalWrite(h2,0);
  digitalWrite(h3,0);
  digitalWrite(h4,0);

  Serial.println("begin");

}

void drive(char d){  
  // d='S'  -> STOP
  // d='F'  -> Forward
  // d='B'  -> Reverse
    leftTrack(d);
    rightTrack(d);  
}

void rightTrack(char d){
  // d='S' Stop
  // d='F' forward
  // d='B' reverse

  if (d=='S'){
    digitalWrite(h3,0);
    digitalWrite(h4,0);
    return;
  }

  if (d=='F'){
    digitalWrite(h3,0);
    digitalWrite(h4,1);
    return;
  }

  if (d=='B'){
    digitalWrite(h3,1);
    digitalWrite(h4,0);
    return;
  }
}

void leftTrack(char d){
  // d='S'  Stop
  // d='F'  Forward
  // d='B' Reverse

  if (d=='S') {
    digitalWrite(h1,0);
    digitalWrite(h2,0);
    return;
  }

  if (d=='F') {
    digitalWrite(h1,0);
    digitalWrite(h2,1);
    return;
  }

  if (d=='B') {
    digitalWrite(h1,1);
    digitalWrite(h2,0);
    return;
  }
}

void spin(char d){
  // spin around by turning one track forward, and the other track in reverse
  if (d=='R') {
    // right track reverse
    rightTrack('B');
    // left track forward
    leftTrack('F');
    return;
  }
  // spin around the other way..
  if (d=='L') {    
    // right track forward
    rightTrack('F');
    // left track reverse
    leftTrack('B');
    return;
  }
}

void turn(char d){
  // turn left while driving forward
  if (d=='G'){    
    // left track stops
    leftTrack('S');
    // right track stops
    rightTrack('F');
  }

  // turn right while driving forward
  if (d=='I'){
    // left track forward
    leftTrack('F');
    // right track stops
    rightTrack('S');
  }

  // turn left while driving in reverse
  if (d=='H'){
    // left track stops
    leftTrack('S');
    // right track reverse
    rightTrack('B');
  }
  // turn right while driving in reverse
  if (d=='J'){
    // left track reverse
    leftTrack('B');
    // right track in stops
    rightTrack('S');
  }
}

void loop() {

   if (SerialBT.available()) {
     char c = SerialBT.read();
     if (c !='S') Serial.println(c);

     switch (c){
      case ('S'): // stop
        drive('S');
        break;
      case ('F'): // Forward        
        drive(c); 
        break;
      case ('B'): // Reverse
        drive(c);
        break;
      case('R'): //spin right
        spin(c);
        break;
      case('L'): //spin left
        spin(c);
        break;
      case('G'): // Forward and Left
        turn(c);
        break;
      case('I'): // Forward and Right
        turn(c);
        break;
      case('H'): // Reverse and Left
        turn(c);
        break;
      case('J'): // Reverse and Right
        turn(c);
        break;
      default:
        drive('S');
        break;  
    } // end switch


   }
}

Sketch uit video 5

In de vijfde video bouw ik het programma helemaal opnieuw op. De versie hieronder is een beetje aangepast.

#include "BluetoothSerial.h"
#include <ESP32Servo.h>
#include "DFRobotDFPlayerMini.h"
#include "Adafruit_NeoPixel.h"

BluetoothSerial SerialBT;
Servo servo1;
Servo servo2;
DFRobotDFPlayerMini myDFPlayer;
Adafruit_NeoPixel pixels(58, 5, NEO_GRB + NEO_KHZ800);

// #define output_x1  0 // as input it is always pulled up. As output it outputs PWM signal at boot
// #define gpoi    1    // TX pin, better not use
// #define output_x2  2 // connected to on-board LED, must be left floating or LOW to enter flashing mode
// #define gpoi    3 // RX pin, better not use
#define LED1       4 
#define neopxls    5 // also SS (slave select) for SPI bus, outputs PWM signal at boot
// #define gpoi    6 // Cannot use, connected to the integrated SPI flash
// #define gpoi    7 // Cannot use, connected to the integrated SPI flash
// #define gpoi    8 // Cannot use, connected to the integrated SPI flash
// #define gpoi    9 // Cannot use, connected to the integrated SPI flash
// #define gpoi   10 // Cannot use, connected to the integrated SPI flash
// #define gpoi   11 // Cannot use, connected to the integrated SPI flash
#define echo      12 // oke to use but boot fails if pulled high
#define LED2      13
#define bumper1   14 // outputs PWM signal at boot  // rear right bumper
// #define gpoi   15 // outputs PWM signal at boot
#define RXD2      16 // RX for serial2
#define TXD2      17 // TX for serial2
#define h3        18 // also CLOCK for SPI bus
#define h2        19 // also MISO for SPI bus
#define step      21 // also i2c DATA pin
#define dir       22 // also i2c CLOCK pin
#define h1        23 // also MOSI for SPI bus
#define servoPin2 25 // 
#define h4        26
#define servoPin1 27
#define trigger   32
#define bumper3   33                          // front right bumper
#define bumper2   34 // input only            // rear left bumper
#define bumper4   35 // input only            // front left bumper
//#define input_x1  36 // input only
#define dfNotBusy 39 // input only // DF Player Busy signal (active low).

  // 1 = I am the awesomo 4000 
  // 2 = what?
  // 3 = weak
  // 4 = system overloading
  // 5 = ah, ah, awesomo needs to rest, feeling faint
  // 6 = I am Awesomo
  // 7 = Awesomo does not understand
  // 8 = Lame!
  // 9 = Weak (nogmaals, zie ook 3)
  // 10 = tututut
  // 11 = no way
  // 12 = Awesomo is re-organizing your stuff for you
  // 13 = Awesomo will answer the door
  // 14 = Haah
  // 15 = Awesomo was not programmed for that function
  // 16 = dark voice: I am the awesomo 4000
  // 17 = dark voice: what?
  // 18 = dark voice: weak
  // 19 = dark voice: system overloading
  // 20 = dark voice: awesomo needs to rest, feeling faint
  // 21 = dark voice: I am Awesomo
  // 22 = dark voice: Awesomo does not understand
  // 23 = dark voice: Lame!
  // 24 = dark voice: Weak (nogmaals, zie ook 18)
  // 25 = dark voice: tututut
  // 26 = dark voice: No Way  
  // 27 = dark voice: Awesomo is re-organizing your stuff for you
  // 28 = dark voice: Awesomo will answer the door
  // 29 = dark voice: Haah
  // 30 = dark voice: Awesomo was not programmed for that function
  // 31 = dark voice: adem halen..
  // 32 = knight rider

int shortClips[]={2,3,8,11,14};
int colorWheelMode=0;
TaskHandle_t Task1;
unsigned long inactivity_counter=0;
unsigned long last_activity=millis();
bool knightRiderMode=false;

void setup() {
  // create a task for the second core.
  xTaskCreatePinnedToCore(SecondCoreCode,"Task1",5000,NULL,0,&Task1,0);


  pinMode(LED1,OUTPUT) ; 
  digitalWrite(LED1,HIGH);
  pinMode(LED2,OUTPUT) ; 
  digitalWrite(LED2,HIGH);

  pixels.begin();
  pixels.clear();
  pixels.show();
  
  pinMode(dfNotBusy,INPUT);

  Serial2.begin(9600, SERIAL_8N1, RXD2, TXD2);
  myDFPlayer.begin(Serial2,false,true);
  myDFPlayer.volume(20);

  SerialBT.begin("Awesomo32"); //Bluetooth device name 
  Serial.begin(115200);
  // H-Bridge
  pinMode(h1, OUTPUT);
  pinMode(h2, OUTPUT);
  pinMode(h3, OUTPUT);
  pinMode(h4, OUTPUT);

  digitalWrite(h1,0);
  digitalWrite(h2,0);
  digitalWrite(h3,0);
  digitalWrite(h4,0);

  // Bumpers
  pinMode(bumper1,INPUT_PULLUP);
  pinMode(bumper2,INPUT);         // gpio 34 has no internal pullup. This needs a hardware pull up (10k)
  pinMode(bumper3,INPUT_PULLUP);
  pinMode(bumper4,INPUT);         // gpio 35 has no internal pullup. This needs a hardware pull up (10k)

  // Stepper motor driver
  pinMode(step, OUTPUT);
  pinMode(dir, OUTPUT);

  // Sonar sensor
  pinMode(trigger,OUTPUT);
  pinMode(echo,INPUT);
  digitalWrite(trigger,0);  

  // Allow allocation of all timers (this is for the servos)
	ESP32PWM::allocateTimer(0);
	ESP32PWM::allocateTimer(1);
	ESP32PWM::allocateTimer(2);
	ESP32PWM::allocateTimer(3);
	servo1.setPeriodHertz(50);    // standard 50 hz servo
  servo2.setPeriodHertz(50);    // standard 50 hz servo
	servo1.attach(servoPin1, 1000, 2000); // attaches the servo on pin  
  servo2.attach(servoPin2, 1000, 2000); // attaches the servo on pin    
  drive('S');
  Serial.println("begin");

  myDFPlayer.play(1); 

}

  void SecondCoreCode(void * parameter){
    while(1){
      ledpanel();
      colorWheels();
      inactivity_counter = (millis() - last_activity) / 1000;
      Serial.print("inactive for :");
      Serial.println(inactivity_counter);
      if (inactivity_counter > 60) {
        knightRider();
      }
      delay(10);
    }
  }

  void knightRider(){
    myDFPlayer.play(32); 
    knightRiderMode=true;
    delay(250);
    while (digitalRead(dfNotBusy)==false){
      pixels.clear();
      for (int i = 41 ; i < 49 ; i=i+2){ 
        pixels.setPixelColor(i,pixels.Color(60,0,0));
        pixels.show();   
        delay(150);
        pixels.setPixelColor(i,pixels.Color(0,0,0));
        pixels.show();    
      }
      for (int i = 45 ; i > 41 ; i=i-2){
        pixels.setPixelColor(i,pixels.Color(60,0,0));
        pixels.show();   
        delay(150);
        pixels.setPixelColor(i,pixels.Color(0,0,0));
        pixels.show();    
      }
      pixels.clear();
      pixels.show();  
    }
    knightRiderMode=false;
    last_activity = millis();
  }

  void colorMouth(){
    if(digitalRead(dfNotBusy)){
      digitalWrite(LED1,HIGH);
      digitalWrite(LED2,HIGH);
      pixels.setPixelColor(56,pixels.Color(0,150,0));
      pixels.setPixelColor(57,pixels.Color(0,150,0));
      pixels.show();       
      delay(150);    
    } else {
      pixels.setPixelColor(56,pixels.Color(150,0,0));      
      pixels.setPixelColor(57,pixels.Color(150,0,0));      
      pixels.show();
      digitalWrite(LED1,LOW);
      digitalWrite(LED2,LOW);
      delay(random(150));
      pixels.setPixelColor(56,pixels.Color(0,0,0));
      pixels.setPixelColor(57,pixels.Color(0,0,0));
      pixels.show();
      digitalWrite(LED1,HIGH);
      digitalWrite(LED2,HIGH);
      delay(random(150));
      
      if (knightRiderMode) return;
      last_activity = millis();
    }
  }

  void ledpanel(){
    if (knightRiderMode) return;
    // base color:
    for (int i=32; i<55; i++)   pixels.setPixelColor(i,pixels.Color(0,0,0)) ; 
    for (int i=32; i<55; i=i+2) pixels.setPixelColor(i,pixels.Color(0,50,50));

    // effect color
    const int leds[]={33,35,37,39,41,43,45,47,49,51,53,55};
    int L1=leds[random(12)];
    int L2=leds[random(12)];
    int L3=leds[random(12)];
    pixels.setPixelColor(L1,pixels.Color(random(60),random(60),random(60)));
    pixels.setPixelColor(L2,pixels.Color(random(60),random(60),random(60)));
    pixels.setPixelColor(L3,pixels.Color(random(60),random(60),random(60)));
    pixels.show();
    colorMouth();
    pixels.setPixelColor(L1,pixels.Color(0,0,0));
    pixels.setPixelColor(L2,pixels.Color(0,0,0));
    pixels.setPixelColor(L3,pixels.Color(0,0,0));
    pixels.show();
    colorMouth();
  }

  void colorWheels(){
  // this void uses the global variable colorWheelMode
  // colorWheelMode = -1  ->  a red segments rotates in reverse
  // colorWheelMode = 1   ->  a green segments rotates forward
  // colorWheelMode = 0   ->  only the background color is shown, nothing rotates
  // colorWheelMode = 2   ->  the wheels are solid red
  // colorWheelMode = 3   ->  the wheels are solid green
  // colorWheelMode = 4   ->  the wheels are solid blue

  if (colorWheelMode == 2 ) {
    for (int y=0 ; y<32 ;y=y+1){pixels.setPixelColor(y,pixels.Color(128,0,0)); }
    pixels.show();
    return;
  }
  if (colorWheelMode == 3 ) {
    for (int y=0 ; y<32 ;y=y+1){pixels.setPixelColor(y,pixels.Color(0,128,0)); }
    pixels.show();
    return;
  }
  if (colorWheelMode == 4 ) {
    for (int y=0 ; y<32 ;y=y+1){pixels.setPixelColor(y,pixels.Color(0,0,128)); }
    pixels.show();
    return;
  }
  
  static byte r,g,b;
  int k;
  int p[]={ 0, 3, 5, 8,11,14} ; // wheel 1
  int q[]={30,28,25,22,19,17} ; // wheel 2
  static int x = 0;
  // set all pixels (in the color wheels) to one color;
  for (int y=0 ; y<32 ;y=y+1){pixels.setPixelColor(y,pixels.Color(20,10,10)); }
  // next, set one of the pixels to solid red or green

  if ( colorWheelMode == -1 ) {k = 5 - x; r=255;g=0;b=0;}
  if ( colorWheelMode == 1  ) {k = x;     r=0  ;g=255;b=0 ;}
  if ( colorWheelMode != 0) {
    pixels.setPixelColor(p[k],pixels.Color(r,g,b));     
    pixels.setPixelColor(q[k],pixels.Color(r,g,b));     
  }
  // show it..
  pixels.show();

  // increase x for the next round. (remember x is a static variable, it will keep its value)
  if (x++ >= 5) x=0;
}
  
void rightArm(char d){
  if (d=='S') {servo2.write(90);  return;}
  if (d=='F') {servo2.write(50);  return;}
  if (d=='B') {servo2.write(130); return;}
}

void leftArm(char d){
  if (d=='S') {servo1.write(90);  return;}
  if (d=='F') {servo1.write(120); return;}
  if (d=='B') {servo1.write(50); return;}
}

int readBumpers(){
  int ret=0;
  if (digitalRead(bumper1)) return 1; // rear right
  if (digitalRead(bumper2)) return 2; // rear left
  if (digitalRead(bumper3)) return 3; // front right
  if (digitalRead(bumper4)) return 4; // front left
  return ret;
}

void headTurn(int d ){
  // d=0 look right
  // d=1 look left
  digitalWrite(dir,d);
  for (int x=0 ; x<300 ; x++){
    digitalWrite(step,1);
    delay(1);
    digitalWrite(step,0);
    delay(1);
  }
}

float getDistance(){
  unsigned long duration =0;
  float d;
  while (duration < 100){
    digitalWrite(trigger,1);
    delayMicroseconds(10);
    digitalWrite(trigger,0);
    delayMicroseconds(2);
    duration = pulseIn(echo, HIGH,12000);
    delayMicroseconds(10);
  }
  d = duration * 0.017;
  d = constrain(d,4,200);
  return d;
}

void drive(char d){  
    leftTrack(d);
    rightTrack(d);  
}

void rightTrack(char d){
  // d='S' Stop
  // d='F' forward
  // d='B' reverse

  rightArm(d);

  if (d=='S'){
    digitalWrite(h3,0);
    digitalWrite(h4,0);
    return;
  }

  if (d=='F'){
    digitalWrite(h3,0);
    digitalWrite(h4,1);
    return;
  }

  if (d=='B'){
    digitalWrite(h3,1);
    digitalWrite(h4,0);
    return;
  }
}

void leftTrack(char d){
  // d='S'  Stop
  // d='F'  Forward
  // d='B' Reverse

  leftArm(d);

  if (d=='S') {
    digitalWrite(h1,0);
    digitalWrite(h2,0);
    return;
  }

  if (d=='F') {
    digitalWrite(h1,0);
    digitalWrite(h2,1);
    return;
  }

  if (d=='B') {
    digitalWrite(h1,1);
    digitalWrite(h2,0);
    return;
  }
}

void spin(char d){
  // spin around by turning one track forward, and the other track in reverse
  if (d=='R') {
    // right track reverse
    rightTrack('B');
    // left track forward
    leftTrack('F');
    return;
  }
  // spin around the other way..
  if (d=='L') {    
    // right track forward
    rightTrack('F');
    // left track reverse
    leftTrack('B');
    return;
  }
}

void turn(char d){
  // turn left while driving forward
  if (d=='G'){    
    // left track stops
    leftTrack('S');
    // right track stops
    rightTrack('F');
  }

  // turn right while driving forward
  if (d=='I'){
    // left track forward
    leftTrack('F');
    // right track stops
    rightTrack('S');
  }

  // turn left while driving in reverse
  if (d=='H'){
    // left track stops
    leftTrack('S');
    // right track reverse
    rightTrack('B');
  }
  // turn right while driving in reverse
  if (d=='J'){
    // left track reverse
    leftTrack('B');
    // right track in stops
    rightTrack('S');
  }
}

void loop() {

    int b=readBumpers();
    // 1 == right rear
    // 2 == left rear
    // 3 == right front
    // 4 == left front

    if (b>0) {      
      // play a random short clip // {2,3,8,11,14};
      if (digitalRead(dfNotBusy) and colorWheelMode != 2) {
        myDFPlayer.play(shortClips[random(5)]);                  
      }
      colorWheelMode = 2;
    } else {
      if (colorWheelMode == 2 ) colorWheelMode = 0;
    }

   if (SerialBT.available()) {
     char c = SerialBT.read();
     if (c !='S') Serial.println(c);

     switch (c){
      case ('S'): // stop
        colorWheelMode = 0;
        drive('S');
        break;
      case ('F'): // Forward        
        if ( readBumpers() < 3 ) { drive(c); }
        colorWheelMode = 1;
        break;
      case ('B'): // Reverse
        if (readBumpers()!= 1 and readBumpers() !=2 )  drive(c);
        colorWheelMode = -1;
        break;
      case('R'): //spin right
        colorWheelMode = 1;
        spin(c);
        break;
      case('L'): //spin left
        colorWheelMode = 1;
        spin(c);
        break;
      case('G'): // Forward and Left
        colorWheelMode = 1;
        turn(c);
        break;
      case('I'): // Forward and Right
        colorWheelMode = 1;
        turn(c);
        break;
      case('H'): // Reverse and Left
        colorWheelMode = -1;
        turn(c);
        break;
      case('J'): // Reverse and Right
        colorWheelMode = -1;
        turn(c);
        break;
      case('X'): // switch to auto drive
        colorWheelMode = 0;
        autoDrive();
        break;
      default:
        drive('S');
        break;  
    } // end switch


   }
}

void autoDrive() {
  while(1){
    while(SerialBT.available()){
      char c= SerialBT.read();
      if (c=='x'){
        colorWheelMode = 0;
        drive('S');
        return;
      }
    }

    // begin driving
    drive('F');    
    colorWheelMode = 1;

    int b=readBumpers();
    // 1 == right rear
    // 2 == left rear
    // 3 == right front
    // 4 == left front

    if (b>0) {
      colorWheelMode = 2;
      // play a random short clip // {2,3,8,11,14};
      myDFPlayer.play(shortClips[random(5)]);                  
    }

    if (b==0){
      float d = getDistance();
      if (d<30){
        colorWheelMode = 2;
        drive('S');
        // play a random short clip // {2,3,8,11,14};
        myDFPlayer.play(shortClips[random(5)]);    

        float r,l,m;
        m=getDistance();
        headTurn(0);
        r=getDistance();
        headTurn(1);
        headTurn(1);
        l=getDistance();
        headTurn(0);

        Serial.print("midden= ");
        Serial.println(m);
        Serial.print("rechts= ");
        Serial.println(r);
        Serial.print("links = ");
        Serial.println(l);
        
        if ( (m>l) and (m>r) ) {
          colorWheelMode = -1;
          drive('S');
          spin('R');
          delay(1000);
          drive('S');
        }

        if ( (l>m) and (l>r) ) {
          b=4;
        }

        if ( (r>m) and (r>l) ){
          b=3;
        }
      }

    }

    switch (b){
      case(0):
        break;
      case(1):
        colorWheelMode = 1;
        drive('F');

        delay(300);
        drive('S');
        turn('I');
        delay(300);
        drive('S');
        break;
      case(2):  
        colorWheelMode = 1;
        drive('F');
        delay(600);
        drive('S');
        turn('G');
        delay(600);
        drive('S');
        break;
      case(3):
        colorWheelMode = -1;
        drive('B');        
        delay(300);
        drive('S');
        turn('H');
        delay(600);
        drive('S');
        break;
      case(4):
        colorWheelMode = -1;
        drive('B');        
        delay(300);
        drive('S');
        turn('J');
        delay(600);
        drive('S');
        break;
    }

  }
}