MCP4921 - 12 bit DAC

De MCP4921 is een 12 bits Digitaal naar Analoog Converter (DAC) met een seriële SPI interface.

De SPI Bus

De SPI bus is een bus systeem. Op de bus wordt een master aangesloten en meerdere slaves. De master activeert een slave met behulp van de SS lijn (Slave select), alleen de actieve slave kan met de master communiceren.
Alle aangesloten apparaten maken gebruik van dezelfde data- en kloklijnen (daarom heet het ook een bussysteem).
In de afbeelding hieronder zie je de gebruikte signalen. Jammer genoeg worden in datasheets niet altijd de zelfde namen gebruikt, bijvoorbeeld MOSI (Master Out, Slave In) wordt vaak gewoon Data In genoemd.

Aansluiten op Arduino

Dit zijn de aansluitingen:

En zo ziet het er uit op het bread board:

Arduino Sketch

In mijn video op youtube leg ik in detail uit hoe de seriële communicatie met deze chip werkt. Hieronder vind je de gebruikte sketch uit de video:

//--------------------------------------------
// 12 bit ADC to DAC Example for MCP3202 and MCP4921
// Bart Venneker 2015
//--------------------------------------------
// connections for the ADC mcp3202
// arduino pin 10 = SS (Slave select, pin 1 the chip)
// arduino pin 11= Data In (pin 5 on device)
// arduino pin 12= Data out (pin 6 on device)
// arduino pin 13= clock (pin 7 on device)
//
// Connections for the DAC mcp4921
// arduino pin 9 = SS (Slave select, pin 2 on the chip)
// arduino pin 11= Data In (pin 4 on device)
// arduino pin 13= clock (pin 3 on device)
// output of the DAC goes to the scope (pin 8 on the chip)
// 
// Supply a signal to channel 0 of the ADC (pin 2 on the chip)
// and it will be reproduced by the DAC.
// See http://youtu.be/5vOGjIEh7Uk for more info (in DUTCH!)
#include <SPI.h>
#define CS_ADC 10
#define CS_DAC 9

void setup()
{   
  pinMode(CS_ADC,OUTPUT);
  digitalWrite(CS_ADC,HIGH);
  pinMode(CS_DAC,OUTPUT);
  digitalWrite(CS_DAC,HIGH);
  SPI.begin();
  SPI.setClockDivider(SPI_CLOCK_DIV2);
}

void loop()
{
  int analogValue;
  analogValue = Read3202(0,CS_ADC);
  Write4921(analogValue, CS_DAC) ;
}

int Read3202(int CHANNEL, int CS){
  int msb;
  int lsb;
  int commandBytes = B10100000 ;             // channel 0		 	
  if (CHANNEL==1) commandBytes = B11100000 ;  // channel 1 
  digitalWrite(CS, LOW);
  SPI.transfer (B00000001);                  // Start bit
  msb = SPI.transfer(commandBytes) ;
  msb = msb & B00001111;
  lsb = SPI.transfer(0x00);
  digitalWrite(CS, HIGH);
  return ((int) msb) <<8 | lsb;
}  

void Write4921(int value, int CS) {
  byte data;
  digitalWrite(CS, LOW);
  data = highByte(value);
  data = B00001111 & data;
  data = B00110000 | data;
  SPI.transfer (data); 
  data = lowByte(value);
  SPI.transfer (data); 
  digitalWrite(CS, HIGH);
}

MCP4921 - 12 bit DAC

De SPI Bus

Aansluiten op Arduino

Arduino Sketch

Bekijk de video