MCP3202 - 12 bit ADC (dual channel)

De MCP3202 is een 2 kanaals 12 bits Analoog naar Digitaal Converter (ADC) met een seriële SPI interface.

De SPI Bus

De SPI bus is een bus systeem. Op de bus wordt een master aangesloten en meerdere slaves. De master activeert een slave met behulp van de SS lijn (Slave select), alleen de actieve slave kan met de master communiceren.
Alle aangesloten apparaten maken gebruik van dezelfde data- en kloklijnen (daarom heet het ook een bussysteem).
In de afbeelding hieronder zie je de gebruikte signalen. Jammer genoeg worden in datasheets niet altijd de zelfde namen gebruikt, bijvoorbeeld MOSI (Master Out, Slave In) wordt vaak gewoon Data In genoemd.

Aansluiten op Arduino

Dit zijn de aansluitingen:

En zo ziet het er uit op het bread board:

Arduino Sketch

In mijn video op youtube leg ik in detail uit hoe de communicatie met deze chip werkt. Hieronder vind je de gebruikte sketch uit de video:

//--------------------------------------------
// 12 bit ADC Example for MCP3202
// Bart Venneker 2015
//--------------------------------------------
// pin 10 (or choose your own) = SS (Slave select, pin 1 on device)
// pin 11= Data In (pin 5 on device)
// pin 12= Data out (pin 6 on device)
// pin 13= clock (pin 7 on device)
//
// Use a potentiometer to supply a voltage between 0 and 5volt to
// input channel 0 (pin 2 on the chip) or channel 1 (pin 3 on the chip)
//
// See https://www.youtube.com/watch?v=oTeE6NI3Lus for more info (in DUTCH!!)
#include <SPI.h>

#define CS_3202 10

void setup()
{
  Serial.begin(9600);
  pinMode(CS_3202,OUTPUT);
  digitalWrite(CS_3202,HIGH);
  SPI.begin();
  SPI.setClockDivider(SPI_CLOCK_DIV8);
}

void loop()
{
  Serial.print("CH0 =");
  Serial.println(Read3202(0,CS_3202));   
  Serial.print("CH1 =");
  Serial.println(Read3202(1,CS_3202));   
  delay(1000);
}

int Read3202(int CHANNEL, int CS){
  int msb;
  int lsb;
  int commandBytes = B10100000 ;              // channel 0		 	
  if (CHANNEL==1) commandBytes = B11100000 ;  // channel 1 
  digitalWrite(CS, LOW);
  SPI.transfer (B00000001);                   // Start bit
  msb = SPI.transfer(commandBytes) ;
  msb = msb & B00001111;
  lsb = SPI.transfer(0x00);
  digitalWrite(CS, HIGH);
  return ((int) msb) <<8 | lsb;
}

MCP3202 - 12 bit ADC (dual channel)

De SPI Bus

Aansluiten op Arduino

Arduino Sketch

Bekijk de video